CSIV Scoring

**** SPSS syntax to compute Circumplex Scales of Interpersonal Values scale scores (and other indices)

* Compute raw CSIV octant scores.

* PA = Agentic, BC = Agentic & Uncommunal, DE = Uncommunal, FG = Unagentic & Uncommunal

* HI = Unagentic, JK = Unagentic & Communal, LM = Communal, NO = Agentic & Communal.

COMPUTE PA = (item01+item09+item17+item25+item33+item41+item49+item57)/8.

COMPUTE BC = (item04+item12+item20+item28+item36+item44+item52+item60)/8.

COMPUTE DE = (item07+item15+item23+item31+item39+item47+item55+item63)/8.

COMPUTE FG = (item02+item10+item18+item26+item34+item42+item50+item58)/8.

COMPUTE HI = (item05+item13+item21+item29+item37+item45+item53+item61)/8.

COMPUTE JK = (item08+item16+item24+item32+item40+item48+item56+item64)/8.

COMPUTE LM = (item03+item11+item19+item27+item35+item43+item51+item59)/8.

COMPUTE NO = (item06+item14+item22+item30+item38+item46+item54+item62)/8.

* Compute scores for the overall bipolar X (communal) and Y (agentic) vectors.

COMPUTE AGENTIC = 0.25*(PA-HI+(.707*(BC+NO-FG-JK))).

COMPUTE COMMUNAL = 0.25*(LM-DE+(.707*(NO+JK-FG-BC))).

*** The above commands are all you need to do the basic scoring.

*** The code below are examples of how to compute additional scores or indices.

* "Structural Summary" Parameters.

* Compute "vector length" or "amplitude" (AMP).
COMPUTE AMP = SQRT((AGENTIC**2)+(COMMUNAL**2)).
* Compute overall mean or "response elevation" (ELE).
COMPUTE ELE = MEAN(PA,BC,DE,FG,HI,JK,LM,NO).
* Compute Sum of Squared Deviations.
COMPUTE SStot =((PA-ELE)**2)+((BC-ELE)**2)+((DE-ELE)**2)+((FG-ELE)**2)+((HI-ELE)**2)+((JK-ELE)**2)+((LM-ELE)**2)+((NO-ELE)**2).
* Compute Circumplex Goodness-of-Fit (R-squared = SSpredicted / SSobserved).
COMPUTE R2 =(4*(AMP**2)/SStot).

* NOTE: A simpler SPSS command to compute R2 (without computing SStot above) is:.
COMPUTE R2 =(4*(AMP**2)/((VARIANCE(PA,BC,DE,FG,HI,JK,LM,NO))*7)).
* Compute Angular Displacement or Circumplex Angle (ANG)
COMPUTE Slope = AGENTIC/COMMUNAL.
IF (AGENTIC>0 and COMMUNAL>0) ANG = 000+artan(Slope)*(180/3.14159).
IF (AGENTIC>0 and COMMUNAL<0) ANG = 180+artan(Slope)*(180/3.14159).
IF (AGENTIC<0 and COMMUNAL>0) ANG = 360+artan(Slope)*(180/3.14159).
IF (AGENTIC<0 and COMMUNAL<0) ANG = 180+artan(Slope)*(180/3.14159).

* Compute z-scores.

* First, insert the means (M) and standard deviations (SD) from a relevant comparison sample.

* The following Ms and SDs are from a sample of 1,200 University of Idaho undergraduates.

COMPUTE M_PA = 2.53.

COMPUTE M_BC = 1.38.

COMPUTE M_DE = 1.10.

COMPUTE M_FG = 1.66.

COMPUTE M_HI = 1.77.

COMPUTE M_JK = 2.67.

COMPUTE M_LM = 2.83.

COMPUTE M_NO = 2.93.

COMPUTE SD_PA = 0.63.

COMPUTE SD_BC = 0.71.

COMPUTE SD_DE = 0.70.

COMPUTE SD_FG = 0.78.

COMPUTE SD_HI = 0.75.

COMPUTE SD_JK = 0.71.

COMPUTE SD_LM = 0.69.

COMPUTE SD_NO = 0.57.

COMPUTE M_AGENTIC = 0.30.

COMPUTE M_COMMUNAL = 1.46.

COMPUTE SD_AGENTIC = 0.65.

COMPUTE SD_COMMUNAL = 0.74.

* Then compute z-scores.

COMPUTE zPA = (PA-M_PA)/SD_PA.

COMPUTE zBC = (BC-M_BC)/SD_BC.

COMPUTE zDE = (DE-M_DE)/SD_DE.

COMPUTE zFG = (FG-M_FG)/SD_FG.

COMPUTE zHI = (HI-M_HI)/SD_HI.

COMPUTE zJK = (JK-M_JK)/SD_JK.

COMPUTE zLM = (LM-M_LM)/SD_LM.

COMPUTE zNO = (NO-M_NO)/SD_NO.

compute zAGENTIC = (AGENTIC - M_AGENTIC )/SD_AGENTIC .

compute zCOMMUNAL = (COMMUNAL - M_COMMUNAL)/SD_COMMUNAL.

* Compute ipsative scores.

COMPUTE iPA=(PA-ELE).

COMPUTE iBC=(BC-ELE).

COMPUTE iDE=(DE-ELE).

COMPUTE iFG=(FG-ELE).

COMPUTE iHI=(HI-ELE).

COMPUTE iJK=(JK-ELE).

COMPUTE iLM=(LM-ELE).

COMPUTE iNO=(NO-ELE).