CSIE - Scoring
 

Home Up

 

Below is a sample SPSS program for scoring the CSIE.

 

* Compute raw octant scores (each raw octant score = mean of 4 items).

* PA = Agentic, BC = Agentic & Uncommunal, DE = Uncommunal, FG = Unagentic & Uncommunal

* HI = Unagentic, JK = Unagentic & Communal, LM = Communal, NO = Agentic & Communal.

COMPUTE PA = (item04+item12+item20+item28)/4.

COMPUTE BC = (item07+item15+item23+item31)/4.

COMPUTE DE = (item02+item10+item18+item26)/4.

COMPUTE FG = (item05+item13+item21+item29)/4.

COMPUTE HI = (item08+item16+item24+item32)/4.

COMPUTE JK = (item03+item11+item19+item27)/4.

COMPUTE LM = (item06+item14+item22+item30)/4.

COMPUTE NO = (item01+item09+item17+item25)/4.

 

* Compute scores for the overall bipolar X (communal) and Y (agentic) vectors.

COMPUTE AGENTIC  = 0.25*(PA-HI+(.707*(BC+NO-FG-JK))).

COMPUTE COMMUNAL = 0.25*(LM-DE+(.707*(NO+JK-FG-BC))).

 

* "Structural Summary" Parameters.

* Compute "vector length" or "amplitude" (AMP).
COMPUTE AMP = SQRT((AGENTIC**2)+(COMMUNAL**2)).
* Compute overall mean or "response elevation" (ELE).
COMPUTE ELE = MEAN(PA,BC,DE,FG,HI,JK,LM,NO).
* Compute Sum of Squared Deviations.
COMPUTE SStot =((PA-ELE)**2)+((BC-ELE)**2)+((DE-ELE)**2)+((FG-ELE)**2)+((HI-ELE)**2)+((JK-ELE)**2)+((LM-ELE)**2)+((NO-ELE)**2).
* Compute Circumplex Goodness-of-Fit (R-squared = SSpredicted / SSobserved).
COMPUTE R2 =(4*(AMP**2)/SStot).

* NOTE: A simpler SPSS command to compute R2 (without computing SStot above) is:.
COMPUTE R2 =(4*(AMP**2)/((VARIANCE(PA,BC,DE,FG,HI,JK,LM,NO))*7)).
* Compute Angular Displacement or Circumplex Angle (ANG)
COMPUTE Slope = AGENTIC/COMMUNAL.
IF (AGENTIC>0 and COMMUNAL>0) ANG = 000+artan(Slope)*(180/3.14159).
IF (AGENTIC>0 and COMMUNAL<0) ANG = 180+artan(Slope)*(180/3.14159).
IF (AGENTIC<0 and COMMUNAL>0) ANG = 360+artan(Slope)*(180/3.14159).
IF (AGENTIC<0 and COMMUNAL<0) ANG = 180+artan(Slope)*(180/3.14159).

 

* Compute ipsative scores.

COMPUTE iPA=(PA-ELE).

COMPUTE iBC=(BC-ELE).

COMPUTE iDE=(DE-ELE).

COMPUTE iFG=(FG-ELE).

COMPUTE iHI=(HI-ELE).

COMPUTE iJK=(JK-ELE).

COMPUTE iLM=(LM-ELE).

COMPUTE iNO=(NO-ELE).